OpenEdge Development:<br />Programming Interfaces Sharing streams among procedures

Release 10.1A: OpenEdge Development:
Programming Interfaces

Sharing streams among procedures

In some cases, you might want two or more procedures to share the same input or output streams. The following procedures, i-sstrm.p and i-dispho.p, share the same output stream, phonelist. Notice that phonelist is defined as a shared stream in both procedures:
i-sstrm.p
DEFINE NEW SHARED BUFFER xrep FOR salesrep. 
DEFINE NEW SHARED STREAM phonelist. 
OUTPUT STREAM phonelist TO phonefile. 
PAUSE 2 BEFORE-HIDE. 
FOR EACH xrep: 
  DISPLAY xrep WITH FRAME repname 
    TITLE "Creating report for " 2 COLUMNS CENTERED ROW 10. 
  DISPLAY STREAM phonelist xrep WITH 2 COLUMNS STREAM-IO. 
  RUN i-dispho.p. 
END. 
The i-sstrm.p procedure defines a NEW SHARED STREAM called phonelist. The procedure sends the output from the phonelist stream to a file called phonefile. The procedure also calls the i-dispho.p procedure:
i-dispho.p
DEFINE SHARED BUFFER xrep FOR salesrep. 
DEFINE SHARED STREAM phonelist. 
FOR EACH customer OF xrep BY state: 
  DISPLAY STREAM phonelist cust-num name city state phone 
          WITH NO-LABELS STREAM-IO. 
END. 
The i-dispho.p procedure defines the SHARED STREAM phonelist, and displays the information from that stream on the screen. (It is more efficient to place the FOR EACH and DISPLAY statements in the i-sstrm.p procedure. They are in a separate procedure here to illustrate shared streams.)
Note: You cannot define or access shared streams in a persistent procedure. If you do, Progress returns a run-time error when you create the persistent procedure. For more information, see the chapter on persistent procedures in OpenEdge Development: Progress 4GL Handbook .

Sharing streams is much like sharing variables:

You use a regular DEFINE STREAM statement to define a stream that is available only to the current procedure.

To define a shared stream, you define the stream as NEW SHARED in the procedure that creates the stream, and as SHARED in all other procedures that use that stream. If you do not explicitly close the stream, Progress closes it automatically at the end of the procedure in which you defined it.

You define the stream as NEW GLOBAL when you want that stream to remain available even after the procedure that contains the DEFINE NEW GLOBAL SHARED STREAM statement ends.